[Zamknięte] Stoły FTP

polecam stworzyc skrypt ahk z taka zawartoscia:

;
; AutoHotkey Version: 1.x
; Language: English
; Platform: Win9x/NT
; Author: RobinP
;
; Script Function:
; Jumps to the most urgent FT table
;

#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance Force
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
SendMode InputThenPlay

SetTitleMatchMode, 2
SysGet, border, 32
SysGet, caption, 4

border_colour := "ff0000"
border_size := 5
trans := 255
last_table_id := ""

menu, tray, DeleteAll
menu, tray, NoStandard
menu, tray, add, EnableHighlight
menu, tray, add, EnableActivateUnderMouse
menu, tray, add, EnableMouseMove
menu, tray, add, EnableTimeBank
menu, tray, add, DisableAll
menu, tray, add
menu, tray, add, Exit
menu, tray, Check, EnableHighlight
menu, tray, Check, EnableActivateUndermouse
menu, tray, Check, EnableMouseMove
menu, tray, Check, EnableTimeBank

highlightenabled := true
activateundermousenabled := true
mousemoveenabled := true
timebankenabled := true

Loop
{
Sleep,200
if (highlightenabled)
Urgenttable()
if (activateundermousenabled)
activatetableundermouse()
if (timebankenabled)
timebanktables()
}

return

timebanktables()
{
WinGet, id, list, Limit Hold'em, , Full Tilt Poker
Loop, %id%
{
this_id := id%A_Index%
WinGetClass, this_class, ahk_id %this_id%
WinGetTitle, this_title, ahk_id %this_id%
ControlGet, v, Visible, , FTCSkinButton19, ahk_id%this_id%
if (v)
{
ControlClick,FTCSkinButton19, ahk_id%this_id%
}
}
}

Urgenttable()
{
global last_table_id
WinGet, id, list, Limit Hold'em, , Full Tilt Poker
ControlGet, v, Visible, , FTCSkinButton13, ahk_id%last_table_id%
if (!v)
{
makegui()
Loop, %id%
{
this_id := id%A_Index%
WinGetClass, this_class, ahk_id %this_id%
WinGetTitle, this_title, ahk_id %this_id%
ControlGet, v, Visible, , FTCSkinButton13, ahk_id%this_id%
if (v)
{
makegui(this_id)
break
}
}
}
}

activatetableundermouse()
{
MousegetPos,,,WinID
WinGetClass, class, ahk_id %WinID%
;WinGetTitle, title, ahk_id %WinID%
;MsgBox, %title%
if (class="FTC_TableViewFull")
winactivate, ahk_id %WinID%
}

makegui(id="")
{
global last_table_id
global border_colour
global border_size
global trans
global mousemoveenabled

if (id != last_table_id)
{
last_table_id := id

if(!id)
{
Gui, 1: Cancel
Gui, 2: Cancel
Gui, 3: Cancel
Gui, 4: Cancel
return
}

WinGetPos, x, y, w, h, ahk_id%id%
global border
global caption
x := x + border
y := y + border + caption
w := w - (2*border)
h := h - (2*border) - caption

;top
guinum := 1
Gui, %guinum%: +Alwaysontop +Lastfound +Owner
Gui, %guinum%: Color, %border_colour%
WinSet, Transparent, %trans%
Gui, %guinum%: -Caption
Gui, %guinum%: Show, w%w% h%border_size% x%x% y%y% NoActivate

;left
guinum++
Gui, %guinum%: +Alwaysontop +Lastfound +Owner
Gui, %guinum%: Color, %border_colour%
WinSet, Transparent, %trans%
Gui, %guinum%: -Caption
Gui, %guinum%: Show, w%border_size% h%h% x%x% y%y% NoActivate

;bottom
guinum++
Gui, %guinum%: +Alwaysontop +Lastfound +Owner
Gui, %guinum%: Color, %border_colour%
WinSet, Transparent, %trans%
Gui, %guinum%: -Caption
y2 := y + h - border_size
Gui, %guinum%: Show, w%w% h%border_size% x%x% y%y2% NoActivate

;right
guinum++
Gui, %guinum%: +Alwaysontop +Lastfound +Owner
Gui, %guinum%: Color, %border_colour%
WinSet, Transparent, %trans%
Gui, %guinum%: -Caption
x2 := x + w - border_size
Gui, %guinum%: Show, w%border_size% h%h% x%x2% y%y% NoActivate

if (mousemoveenabled)
{
x3 := x + ((w/4)*3)
y3 := y + ((h/4)*3)
;SoundBeep, 750, 100
Coordmode, Mouse, Screen
MouseMove, x3, y3, 0
}
}
}

EnableHighlight:
menu, tray, toggleCheck, EnableHighlight
highlightenabled := !highlightenabled
return

EnableActivateUnderMouse:
menu, tray, toggleCheck, EnableActivateUndermouse
activateundermousenabled := !activateundermousenabled
return

EnableMouseMove:
menu, tray, toggleCheck, EnableMouseMove
mousemoveenabled := !mousemoveenabled
return

EnableTimeBank:
menu, tray, toggleCheck, EnableTimeBank
timebankenabled := !timebankenabled
return

DisableAll:
menu, tray, unCheck, EnableActivateUndermouse
activateundermousenabled := false
menu, tray, unCheck, EnableHighlight
highlightenabled := false
menu, tray, unCheck, EnableTimeBank
timebankenabled := false
menu, tray, unCheck, EnableMouseMove
mousemoveenabled := false
return

Exit:
ExitApp
return

Przy aktywnym stole pokazuje sie czerwona ramka.

Dzięki za pomoc. Jeszcze nie wiem co i jak z tymi skryptami ale jak będę miał trochę wolnego czasu to popróbuje to utworzyć.

Jeszcze raz dzięki.

http://www.autohotkey.com/download/

Stad sciagnij instalke Autohotkey.

Jak juz zainstalujesz, otwierasz notatnik wklejasz to co Ci napisałem w poprzednim poscie i zapisujesz z rozszerzenie .ahk

Potem uruchamiasz i w prawym dolnym rogu pokazuje sie zielona ikonka H. Klikasz prawym i wylaczasz opcje których nie chcesz (ja wylaczylem automatyczne przerzucanie kursora).

Pozdro.

Już działa, o wiele lepiej z tą obwódką czerwoną.
Dzięki

PS. jak masz coś jeszcze ciekawego to podeślij

Pozdro